在shell脚本中解析wmic的输出

小编典典

在shell脚本中解析wmic的输出

java

我试图解析WMIC的输出，然后获取PID。

我的脚本如下：

@echo off

setLocal enableExtensions enableDelayedExpansion

FOR /F "tokens=1* delims=" %%A IN ('"wmic process where(name="java.exe") get ProcessID,commandline| FINDSTR /v "CommandLine" | FINDSTR "TestServer""') DO (
     set "line=%%A"
     @REM echo "%%A"
     for /F "tokens=* delims= " %%C in ("%%A") do (
         echo "%%C"
         echo "%%D"
  )
)

输出如下：

"java  com.test.TestServer                                       7560       "
"%D"
"java  com.test.TestServer                                       7380       "
"%D"

我的目标是获取进程ID。

我已经尝试过将空间作为FOR循环中的delims。然而没有运气。

所以我的问题是如何格式化WMIC的列并获取列？

阅读 277

2020-11-30

共1个答案

小编典典

WMIC使用SQL语法的子集。通过将LIKE运算符与%通配符一起使用，可以在功能上将FINDSTR测试放在WMIC
WHERE子句中。由于它在批处理脚本中，因此%需要加倍。

由于WMIC输出中不再需要CommandLine值，因此解析出ProcessID更加容易。我添加了SessionID以便在末尾放置一个未使用的值，以便更轻松地解析该值，而不必担心FOR
/ F在将WMIC Unicode输出转换为ANSI时以某种方式引入的不必要的回车符。

@echo off
setlocal
set "pid="
for /f "skip=1" %%A in (
  'wmic process where "name='java.exe' and commandline like '%%TestServer%%' and not commandline like '%%CommandLine%%'" get processid^, sessionid'
) do if not defined pid set "pid=%%A"

编辑以回应评论中的问题

WMIC Unicode的FOR / F转换还引入了不需要的行，这些行看起来为空，但实际上包含一个回车符。在上面的代码中，我假设您期望一行，因此我使用IF
DEFINED有效地忽略了多余的尾随“空白”行。

如果期望多个值，则需要另一种方法。额外的FOR /
F循环将删除不需要的回车符，因此这些行实际上变为空行，因此将被忽略。根据您的评论，您似乎不再需要忽略包含“ CommandLine”的命令行。

我不知道您需要使用这些值做什么，因此下面的代码只是回显每个值。我使用SKIP = 1来代替通过FINDSTR传递结果以避免标题行。

@echo off
for /f "skip=1" %%A in (
  'wmic process where "name='java.exe' and commandline like '%%TestServer%%'" get processid'
) do for /f %%B in ("%%A") do echo %%B

2020-11-30