在64位Linux上使用中断0x80

小编典典

在64位Linux上使用中断0x80

linux

我有一个简单的64位汇编程序，该程序用于先打印’O’和’K’，然后打印换行符。但是，永远不会打印“
K”。程序的目标之一是将rax寄存器低位的值打印为ASCII字母。该程序专门用于64位Linux，是出于教学目的而编写的，因此无需使用C风格的系统调用。

我怀疑问题出在mov QWORD [rsp], rax还是mov rcx, rsp。

当前，该程序仅输出’O’，后跟换行符。

如何更改程序以使其使用rax中的值，然后打印“ K”，使完整的输出为“ OK”，然后换行？

bits 64

section .data

o:  db "O"      ; 'O'
nl: dq 10       ; newline

section .text

;--- function main ---
global main         ; make label available to the linker
global _start       ; make label available to the linker
_start:             ; starting point of the program
main:               ; name of the function

;--- call interrupt 0x80 ---
mov rax, 4          ; function call: 4
mov rbx, 1          ; parameter #1 is 1
mov rcx, o          ; parameter #2 is &o
mov rdx, 1          ; parameter #3 is length of string
int 0x80            ; perform the call

;--- rax = 'K' ---
mov rax, 75         ; rax = 75

;--- call interrupt 0x80 ---
sub rsp, 8          ; make some space for storing rax on the stack
mov QWORD [rsp], rax        ; move rax to a memory location on the stack
mov rax, 4          ; function call: 4
mov rbx, 1          ; parameter #1 is 1
mov rcx, rsp            ; parameter #2 is rsp
mov rdx, 1          ; parameter #3 is length of string
int 0x80            ; perform the call
add rsp, 8          ; move the stack pointer back

;--- call interrupt 0x80 ---
mov rax, 4          ; function call: 4
mov rbx, 1          ; parameter #1 is 1
mov rcx, nl         ; parameter #2 is nl
mov rdx, 1          ; parameter #3 is length of string
int 0x80            ; perform the call

;--- exit program ---
mov rax, 1          ; function call: 1
xor rbx, rbx            ; return code 0
int 0x80            ; exit program

阅读 823

2020-06-03

共1个答案

小编典典

显然，您编写了64位程序，并使用了“ int 0x80”指令。但是，“ int 0x80”仅在32位程序中正常工作。

堆栈的地址处于32位程序无法访问的范围内。因此，很有可能“ int 0x80”风格的系统调用不允许访问该存储区。

要解决此问题，有两种可能性：

编译为32位应用程序（使用EAX这样的32位寄存器而不是RAX这样的64位寄存器）。在不使用任何共享库的情况下进行链接时，32位程序将在64位Linux上完美运行。
使用“ syscall”样式的系统调用，而不是“ int 0x80”样式的系统调用。这些与“ int 0x80”样式的用法有很大不同！

32位代码：

mov eax,4    ; In "int 0x80" style 4 means: write
mov ebx,1    ; ... and the first arg. is stored in ebx
mov ecx,esp  ; ... and the second arg. is stored in ecx
mov edx,1    ; ... and the third arg. is stored in edx
int 0x80

64位代码：

mov rax,1    ; In "syscall" style 1 means: write
mov rdi,1    ; ... and the first arg. is stored in rdi (not rbx)
mov rsi,rsp  ; ... and the second arg. is stored in rsi (not rcx)
mov rdx,1    ; ... and the third arg. is stored in rdx
syscall

-编辑-

背景资料：

“ int 0x80”适用于32位程序。从64位程序调用时，其行为与从32位程序中调用（使用32位调用约定）时的行为相同。

这也意味着“ int 0x80”的参数将在 32位寄存器中 传递，而64位寄存器的高32位将被忽略。

（我刚刚在64位Ubuntu 16.10上进行了测试。）

但是，这意味着您在使用“ int 0x80”时只能访问2 ^ 32以下（甚至低于2 ^ 31）的内存，因为您不能在32位寄存器中传递2 ^ 32以上的地址。

如果要写入的数据位于2 ^ 31以下的地址，则可以使用“ int 0x80”来写入数据。如果它位于2 ^ 32以上，则不能。堆栈（RSP）很可能位于2 ^
32以上，因此您不能使用“ int 0x80”将数据写入堆栈。

因为您的程序很可能会使用2 ^ 32以上的内存，所以我写道：“ int 0x80不适用于64位程序。”

2020-06-03